Home | 简体中文 | 繁体中文 | 杂文 | 知乎专栏 | 51CTO学院 | CSDN程序员研修院 | Github | OSChina 博客 | 腾讯云社区 | 阿里云栖社区 | Facebook | Linkedin | Youtube | 打赏(Donations) | About
知乎专栏多维度架构

第 7 章 Token

ERC 代币标准

目录

7.1. Ethereum Wallet 创建ERC20代币合约
7.1.1. 合约文件
7.1.2. 部署合约
7.1.3. 代币转账
7.1.4. Verify And Publish
7.1.5. Links 链接更新
7.2. ERC20 Token Solidity 0.4.24
7.2.1. 构造方法
7.2.2. 官方规定 Method 方法
7.2.2.1. name
7.2.2.2. symbol
7.2.2.3. decimals
7.2.2.4. totalSupply
7.2.2.5. balanceOf
7.2.2.6. transfer
7.2.2.7. approve
7.2.2.8. transferFrom
7.2.2.9. allowance
7.2.3. 事件
7.2.3.1. Transfer
7.2.3.2. Approval
7.3. Netkiller Crowdsale Contract
7.3.1. Solidity 0.4.24
7.3.2. Solidity 0.4.21
7.4. ERC721 - Non-Fungible Tokens
7.4.1.
7.4.2. ERC721Metadata (可选)
7.4.3. ERC721Enumerable (可选)
7.5. 经典参考案例
7.5.1. Enterprise Token Ecosystem (ETE)
7.5.2. 积分链 (PE Chain)
7.5.3. Global star league chain (GSLC)
7.5.4. Kyber Network
7.6. 代币合约官方文档
7.6.1. ERC20
7.6.1.1. 基本Token 官方提供的例子
7.6.1.2. 官方提供的例子 ADVANCED TOKEN
7.6.1.3. Netkiller Basic Token 的例子
7.6.1.4. Netkiller ADVANCED TOKEN
7.6.1.5. 空投代币
7.6.1.5.1. 案例一
7.6.1.5.2. 案例二
7.6.1.5.3. 案例三
7.6.2. ERC223 token standard reference implementation.
7.6.3. ERC721 - Non-fungible Token Standard
7.6.4. ERC827 Token Standard (ERC20 Extension)
7.6.5. ERC875 for non fungible tokens and simple atomic swaps
7.6.6. ERC: Standard URI scheme with metadata, value and byte code

7.1. Ethereum Wallet 创建ERC20代币合约

https://ethereum.org/token

7.1.1. 合约文件

		
pragma solidity ^0.4.16;

interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    // Public variables of the token
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    // 18 decimals is the strongly suggested default, avoid changing it
    uint256 public totalSupply;

    // This creates an array with all balances
    mapping (address => uint256) public balanceOf;
    mapping (address => mapping (address => uint256)) public allowance;

    // This generates a public event on the blockchain that will notify clients
    event Transfer(address indexed from, address indexed to, uint256 value);

    // This notifies clients about the amount burnt
    event Burn(address indexed from, uint256 value);

    /**
     * Constrctor function
     *
     * Initializes contract with initial supply tokens to the creator of the contract
     */
    function TokenERC20(
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    ) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // Update total supply with the decimal amount
        balanceOf[msg.sender] = totalSupply;                // Give the creator all initial tokens
        name = tokenName;                                   // Set the name for display purposes
        symbol = tokenSymbol;                               // Set the symbol for display purposes
    }

    /**
     * Internal transfer, only can be called by this contract
     */
    function _transfer(address _from, address _to, uint _value) internal {
        // Prevent transfer to 0x0 address. Use burn() instead
        require(_to != 0x0);
        // Check if the sender has enough
        require(balanceOf[_from] >= _value);
        // Check for overflows
        require(balanceOf[_to] + _value > balanceOf[_to]);
        // Save this for an assertion in the future
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        // Subtract from the sender
        balanceOf[_from] -= _value;
        // Add the same to the recipient
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        // Asserts are used to use static analysis to find bugs in your code. They should never fail
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    /**
     * Transfer tokens
     *
     * Send `_value` tokens to `_to` from your account
     *
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    /**
     * Transfer tokens from other address
     *
     * Send `_value` tokens to `_to` on behalf of `_from`
     *
     * @param _from The address of the sender
     * @param _to The address of the recipient
     * @param _value the amount to send
     */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    /**
     * Set allowance for other address
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     */
    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    /**
     * Set allowance for other address and notify
     *
     * Allows `_spender` to spend no more than `_value` tokens on your behalf, and then ping the contract about it
     *
     * @param _spender The address authorized to spend
     * @param _value the max amount they can spend
     * @param _extraData some extra information to send to the approved contract
     */
    function approveAndCall(address _spender, uint256 _value, bytes _extraData)
        public
        returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    /**
     * Destroy tokens
     *
     * Remove `_value` tokens from the system irreversibly
     *
     * @param _value the amount of money to burn
     */
    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);   // Check if the sender has enough
        balanceOf[msg.sender] -= _value;            // Subtract from the sender
        totalSupply -= _value;                      // Updates totalSupply
        Burn(msg.sender, _value);
        return true;
    }

    /**
     * Destroy tokens from other account
     *
     * Remove `_value` tokens from the system irreversibly on behalf of `_from`.
     *
     * @param _from the address of the sender
     * @param _value the amount of money to burn
     */
    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);                // Check if the targeted balance is enough
        require(_value <= allowance[_from][msg.sender]);    // Check allowance
        balanceOf[_from] -= _value;                         // Subtract from the targeted balance
        allowance[_from][msg.sender] -= _value;             // Subtract from the sender's allowance
        totalSupply -= _value;                              // Update totalSupply
        Burn(_from, _value);
        return true;
    }
}

		
		

7.1.2. 部署合约

启动 Ethereum Wallet,点击 CONTRACTS 按钮,进入合约管理界面

点击 DEPLOY NEW CONTRACT 按钮,部署一个新合约

复制粘贴合约文件到 SOLIDITY CONTRACT SOURCE CODE 下方

SELECT CONTRACT TO DEPLOY 列表选择 “Token ERC 20”

Initial supply 是初始发行货币量

Token name 是代币名称

Token symbol 是代币符号

拉动滚动调,找到下方 “DEPLOY”按钮,点击该按钮。

输入账号密码,并点击“SEND TRANSACTION” 按钮。

ERC20代币创建完成

7.1.3. 代币转账

进入钱包可以看到当前账号的以太币数量,在下方还能看到 ERC20 代币。

点击 SEND 按钮

填写 TO 地址 和 代币 500 个,点击 SEND 按钮

进入目标账号查看余额。

7.1.4. Verify And Publish

查看合约执行状态等待执行完成 TxReceipt Status:Success

点击合约地址,查看合约

进入 Code 选项卡,点击 Verify And Publish 按钮

输入合约名称 Contract Name,选择编译器版本 Compiler,点击 Fetch From Gist 按钮输入 Gist 上的合约地址。

Optimization 选择 Yes

勾选验证码, 然后点击 Verify And Publish 按钮

合约校验成功

7.1.5. Links 链接更新

复制签名信息

进入 MyEtherWallet 签名页面 https://www.myetherwallet.com/signmsg.html

粘贴签名信息

选择私钥签名

解锁账号

签名,复制 sig 的值

粘贴 sig,然后点击 Verify 按钮

信息填写完成后点击“Send Message” 保存